編號：QA003053
建立日期: 2000年6月15日 最后修改日期：2000年6月15日
所屬類別：

Delphi - Office開發

文章:

    摘要：玩過PowerBuilder的朋友一定知道，PB中最重要的技術就是它的DataWindow技術，用它來設計表單、處理數據錄入、設計報表十分方便。然而Delphi的報表支持功能遠不及PB。Delphi的專業版中包括了QuickReport，不過它是集合由QSD AS（一家挪威公司）授權的報表組件。當然，我們也可以使用外部報表工具，如ReportSmith或Cristal Report。不過控制稍嫌復雜，并且它們與Delphi之間缺少集成性。
    我們在開發《公文管理系統》網絡版時，在實現公文打印時，嘗試過不同的方法來實現。我們的要求是將一篇普通公文按公文格式打印出來，而用戶能對其進行排版進行一些簡單的控制。小輝剛開始是用的QuickReport來試的，效果很不盡人意，特別是對一些中文格式的支持方面；后來小輝一不作二不休，干脆自己手工編寫打印程序，不依賴設計工具，只可惜小輝技術不到家，寫到一半時玩不下去了，只好另找出路。正好那天來了份《中國計算機報》，上面有一篇介紹如何在VB中使用Excel的文章。小輝一想：何不用Delphi將數據發送到Word，由Word來完成編輯排版工作呢？說穿了，就是用OLE自動化技術。
    小輝一試，效果竟還可以。——雖然對于一個程序員來說，自己編的程序中要掛接一個別人的應用程序才能完全實現自己的功能，就象雞群里插只鴨，心里總有點那個。但由于開發任務緊，主任又隔三隔四的來催，雖然最終有點不倫不類，小輝也顧不得那么多了。好了，廢話少說，看看小輝是怎樣實現的吧——
    鏈接：http://www.xiaohui.com
    主持人：由于原鏈接已經失效。我們在這里提供原文：
    一、前　言
    
    　　玩過PowerBuilder的朋友一定知道，PB中最重要的技術就是它的DataWindow技術，用它來設計表單、處理數據錄入、設計報表十分方便。然而Delphi的報表支持功能遠不及PB。Delphi的專業版中包括了QuickReport，不過它是集合由QSD AS（一家挪威公司）授權的報表組件。當然，我們也可以使用外部報表工具，如ReportSmith或Cristal Report。不過控制稍嫌復雜，并且它們與Delphi之間缺少集成性。
    　　我們在開發《公文管理系統》網絡版時，在實現公文打印時，嘗試過不同的方法來實現。我們的要求是將一篇普通公文按公文格式打印出來，而用戶能對其進行排版進行一些簡單的控制。小輝剛開始是用的QuickReport來試的，效果很不盡人意，特別是對一些中文格式的支持方面；后來小輝一不作二不休，干脆自己手工編寫打印程序，不依賴設計工具，只可惜小輝技術不到家，寫到一半時玩不下去了，只好另找出路。正好那天來了份《中國計算機報》，上面有一篇介紹如何在VB中使用Excel的文章。小輝一想：何不用Delphi將數據發送到Word，由Word來完成編輯排版工作呢？說穿了，就是用OLE自動化技術。
    　　小輝一試，效果竟還可以。——雖然對于一個程序員來說，自己編的程序中要掛接一個別人的應用程序才能完全實現自己的功能，就象雞群里插只鴨，心里總有點那個。但由于開發任務緊，主任又隔三隔四的來催，雖然最終有點不倫不類，小輝也顧不得那么多了。好了，廢話少說，看看小輝是怎樣實現的吧——
    
    二、窗體設計
    
    　　說穿了其實很簡單。小輝在這里做了一個簡單的示例程序：
    　　1. 設置窗體Form1的Font.name為‘宋體’，Font.size為12；
    　　2. 窗體上依次放置lable1-labe5五個tLable控件，其caption屬性分別為‘文號’、‘標題’、‘收文單位’、‘正文’、‘發文單位’
    　　3. 在窗體上依次放置 tEdit、tEdit、tEdit、tMemo、tEdit五個編輯控件，其name屬性分別為:ED_WenHao、ED_BiaoTi、ED_ShouWenDanWei、ED_ZhenWen、ED_FaWenDanWei。
    　　4. 在窗體上依次放置兩個tButton控件，其name屬性分別為Btn_PRintToWord、btn_Quit，Caption屬性分別為‘打印’和‘退出’。
    　　窗體設計格式可參考本文末所附圖片。
    
    
    三、代碼設計
    
    　　
    　　程序段如下所示：
    unit Unit1;
    
    interface
    
    uses
    Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
    StdCtrls,OleCtnrs,ComObj;
    
    type
     TForm1 = class(TForm)
     Label1: TLabel;
     Label2: TLabel;
     Label3: TLabel;
     Label4: TLabel;
     Label5: TLabel;
     ED_WenHao: TEdit;
     ED_BiaoTi: TEdit;
     ED_ShouWenDanWei: TEdit;
     ED_ZhenWen: TMemo;
     ED_FaWenDanWei: TEdit;
     Btn_PrintToWord: TButton;
     Btn_Quit: TButton;
     procedure Btn_PrintToWordClick(Sender: TObject);
     procedure Btn_QuitClick(Sender: TObject);
     private
     { Private declarations }
     public
     { Public declarations }
    end;
    
    var
     Form1: TForm1;
    
    implementation
    
    {$R *.DFM}
    
    //開始：數據發送到word事件
    procedure TForm1.Btn_PrintToWordClick(Sender: TObject);
    vAR
     VarWord: Variant;// 創建WORD時所用
    begin
     try
     // 1. 建立OleObject，連接word97
     VarWord:=CreateOleObject('word.basic');
     // 2. 建立Word97的新文件
     VarWord.FileNew;
     // 3. 設置Word97的基本狀態
     VarWord.ViewZoom75; //設置顯示比例為75%
     VarWord.ViewPage; //改為頁面顯示方式
     // 4. 將當前數據控件上的信息發送至Word97
     // 4.1 發送文號數據
     VarWord.CenterPara; //居中
     Varword.font('宋體'); //設置字體
     VarWord.FontSize(14); //設置字號
     varword.insert(#13+#13+ ED_WenHao.Text+#13+#13+#13);
     // 4.2 發送標題數據
     VarWord.font('黑體');
     VarWord.Fontsize(16);
     VarWord.insert( ED_BiaoTi.text+#13);
     // 4.3 發送收文單位數據
     VarWord.LeftPara; //左對齊
     VarWord.Font('宋體');
     VarWord.fontSize(14);
     VarWord.Insert(#13+ ED_ShouWenDanWei.Text+'：'+#13);
     // 4.5 發送正文數據
     VarWord.fontSize(14);
     VarWord.Insert( ED_ZhenWen.Text+#13);
     // 4.6 發送發文單位數據
     VarWord.RightPara; //右對齊
     VarWord.fontSize(14);
     VarWord.Insert( ED_FaWenDanWei.Text+#13);
     // 5 最后設置
     VarWord.StartOfdocument; //到文首
     VarWord.AppMaxiMize; //設置窗口最大化
     VarWord.AppShow; //顯示應用程序
     except
     showmessage('運行 Microsoft Word 失敗！');
     end; //end of try
    end;
    //end：數據發送到word事件
    
    
    //開始：窗口關閉事件
    procedure TForm1.Btn_QuitClick(Sender: TObject);
    begin
     close;
    end;
    //End：窗口關閉事件
    
    end.
    // 這是主程序的尾部
    
    
    四、附　注
    
    一、說明
    　　１、因只是一個演示示例，故沒有與后臺數據庫連接起來，實際操作可將相應的tEdit、tMemo控件用tDBEdit、tDBMemo控件所代替，增加tTable、tDataSource等控件，連接數據庫。
    　　２、本示便沒有考慮如何進行批量打印
    　　３、程序在Pwin97、Delphi 4.0專業版、中文Word97下通過。
    　　４、由于Word有不同的版本，微軟在每種外語中轉換了一些OLE自動化接口，如果用其他版本的Word，本程序運行有可能出錯。
    　　５、可以通過word97幫助中歸結的宏命令來得到相應的驅動命令；亦或可在Word97下單擊［工具］菜單－－單擊［自定義］－－單擊［鍵盤］按鈕，可以查看到Word97中分類別顯示的Word命令。
    
    二、優點與缺點
    
    　　１、通過OLE自動化技術，將公文的排版打印工作交給Word去完成，對最終用戶而言，控制較方便。
    　　２、在Word97的若對數據進行了修改，則不能傳回調用它的主程序，反映到數據庫中。這是它的不便這處。
    　　３、本例只是在特殊情況下的一種應用，若要打印大量數據標簽，制作表格，小輝覺得還是用報表靈活一些

文章來源：小輝程序員之路。